plugins {
	id 'java'
	id 'maven-publish'
	id 'idea'
	id 'eclipse'
	id 'com.matthewprenger.cursegradle' version '1.4.0'
	id 'fabric-loom' version '0.4-SNAPSHOT'
}

boolean dev = System.getenv('RELEASE') == null || System.getenv('RELEASE').equals('false');
ext.buildnumber = System.getenv().BUILD_NUMBER ?: 'custom';

group = 'com.tterrag.blur'
archivesBaseName = "Blur"
version = "${mod_version}-${minecraft_version}+fabric"

sourceCompatibility = '1.8'
targetCompatibility = '1.8'

minecraft {
}

repositories {
	jcenter()
}

dependencies {
	minecraft "com.mojang:minecraft:${minecraft_version}"
	mappings "net.fabricmc:yarn:${mappings_version}"
	modCompile "net.fabricmc:fabric-loader:${fabric_loader_version}"
	modCompile "net.fabricmc.fabric-api:fabric-api:${fabric_version}"
	modCompile "io.github.ladysnake:Satin:${satin_version}"
	include "io.github.ladysnake:Satin:${satin_version}"
	
	modImplementation ("me.sargunvohra.mcmods:autoconfig1u:${project.auto_config_version}")
	include ("me.sargunvohra.mcmods:autoconfig1u:${project.auto_config_version}")
	modImplementation ("me.shedaniel.cloth:config-2:${project.cloth_config_version}")
	include ("me.shedaniel.cloth:config-2:${project.cloth_config_version}")
	modImplementation ("io.github.prospector:modmenu:${project.mod_menu_version}")
	
	implementation 'com.google.code.findbugs:jsr305:3.0.2'
}

processResources {
	inputs.property "version", mod_version

	from(sourceSets.main.resources.srcDirs) {
		include "fabric.mod.json"
		expand "version": mod_version
	}

	from(sourceSets.main.resources.srcDirs) {
		exclude "fabric.mod.json"
	}
}

import org.apache.tools.ant.filters.ReplaceTokens
import groovy.json.JsonSlurper

task createResourcePacks {
	def inputFile = new File("resource_packs.json")
	def json = new JsonSlurper().parseText(inputFile.text)
	json.each {
		def pack_id 	= it.key
		def pack_name   = it.value.name
		def pack_desc 	= it.value.description
		def pack_radius = it.value.radius
		
		def taskName = "createPack" + pack_id.capitalize();
		task "${taskName}" (type: Zip) {
			from ('pack_template') {		
				filter(ReplaceTokens, tokens: [
					mod_version:	project.version.toString(),
					pack_version: 	'3',
					description:	pack_desc.toString(),
					radius: 		pack_radius.toString()
				])
				
				rename(/(.+)\.template/, '$1')
			}
			
			from ('pack_icons') {
				include "${pack_id}.png"
				rename '.+', 'icon.png'
			}
			
			baseName = "Blur " + pack_name
		}
		
		createResourcePacks.finalizedBy taskName
	}
}

// Not necessary atm
// tasks.build.dependsOn createResourcePacks

tasks.curseforge.enabled = !dev && project.hasProperty('curseforge_key')

curseforge {
    if (project.hasProperty('curseforge_key')) {
        apiKey = project.curseforge_key
    }

    project {
        id = project.project_id
        changelogType = 'html'
        changelog = System.getenv('CHANGELOG')
        if (changelog == null || 'none'.equals(changelog)) {
        	changelog = getChangelog() ?: ''
        	changelogType = 'text'
        }
        releaseType = project.release_type
		addGameVersion '1.9.4'
		addGameVersion '1.11.2'
		addGameVersion '1.12'
		addGameVersion '1.12.1'
        mainArtifact(jar) {
            displayName = "Blur ${mod_version}"
        }
    }
}