Architectury port, EMI compat

fabric/build.gradle

@@ -0,0 +1,100 @@
+plugins {
+    id 'com.github.johnrengelman.shadow'
+    id "me.shedaniel.unified-publishing"
+}
+
+architectury {
+    platformSetupLoomIde()
+    fabric()
+}
+
+configurations {
+    common
+    shadowCommon // Don't use shadow from the shadow plugin since it *excludes* files.
+    compileClasspath.extendsFrom common
+    runtimeClasspath.extendsFrom common
+    developmentFabric.extendsFrom common
+    archivesBaseName = rootProject.archives_base_name + "-fabric"
+    version = rootProject.mod_version + "+" + rootProject.minecraft_version
+}
+
+dependencies {
+    modImplementation "net.fabricmc:fabric-loader:${rootProject.fabric_loader_version}"
+    modApi "net.fabricmc.fabric-api:fabric-api:${rootProject.fabric_api_version}"
+    modImplementation include ("maven.modrinth:midnightlib:${rootProject.midnightlib_version}-fabric")
+
+    common(project(path: ":common", configuration: "namedElements")) { transitive false }
+    shadowCommon(project(path: ":common", configuration: "transformProductionFabric")) { transitive false }
+}
+
+processResources {
+    inputs.property "version", rootProject.version
+
+    filesMatching("fabric.mod.json") {
+        expand "version": rootProject.version
+    }
+}
+
+shadowJar {
+    exclude "architectury.common.json"
+
+    configurations = [project.configurations.shadowCommon]
+    archiveClassifier = "dev-shadow"
+}
+
+remapJar {
+    input.set shadowJar.archiveFile
+    dependsOn shadowJar
+}
+
+sourcesJar {
+    def commonSources = project(":common").sourcesJar
+    dependsOn commonSources
+    from commonSources.archiveFile.map { zipTree(it) }
+}
+
+components.java {
+    withVariantsFromConfiguration(project.configurations.shadowRuntimeElements) {
+        skip()
+    }
+}
+
+unifiedPublishing {
+    project {
+        displayName = "Blur+ $rootProject.version - Fabric $project.minecraft_version"
+        releaseType = "$project.release_type"
+        changelog = releaseChangelog()
+        gameVersions = []
+        gameLoaders = ["fabric","quilt"]
+        mainPublication remapJar
+        relations {
+            depends {
+                curseforge = "fabric-api"
+                modrinth = "fabric-api"
+            }
+            includes {
+                curseforge = "midnightlib"
+                modrinth = "midnightlib"
+            }
+        }
+
+        var CURSEFORGE_TOKEN = project.findProperty("CURSEFORGE_TOKEN") ?: System.getenv("CURSEFORGE_TOKEN")
+        if (CURSEFORGE_TOKEN != null) {
+            curseforge {
+                token = CURSEFORGE_TOKEN
+                id = rootProject.curseforge_id
+                gameVersions.addAll "Java 21", project.minecraft_version, project.supported_versions
+            }
+        }
+
+        var MODRINTH_TOKEN = project.findProperty("MODRINTH_TOKEN") ?: System.getenv("MODRINTH_TOKEN")
+        if (MODRINTH_TOKEN != null) {
+            modrinth {
+                token = MODRINTH_TOKEN
+                id = rootProject.modrinth_id
+                version = "$rootProject.version-$project.name"
+                gameVersions.addAll project.minecraft_version, project.supported_versions
+            }
+        }
+    }
+}

fabric/src/main/java/eu/midnightdust/blur/fabric/BlurFabric.java

@@ -0,0 +1,14 @@
+package eu.midnightdust.blur.fabric;
+
+import eu.midnightdust.blur.Blur;
+import eu.midnightdust.blur.util.RainbowColor;
+import net.fabricmc.api.ClientModInitializer;
+import net.fabricmc.fabric.api.client.event.lifecycle.v1.ClientTickEvents;
+
+public class BlurFabric implements ClientModInitializer {
+    @Override
+    public void onInitializeClient() {
+        Blur.init();
+        ClientTickEvents.END_CLIENT_TICK.register(client -> RainbowColor.tick());
+    }
+}

fabric/src/main/resources/fabric.mod.json

@@ -0,0 +1,34 @@
+{
+  "schemaVersion": 1,
+  "id": "blur",
+  "name": "Blur+ (Fabric)",
+  "version": "$version",
+  "environment": "client",
+  "license": "MIT",
+  "icon": "assets/blur/icon.png",
+  "entrypoints": {
+    "client": [
+      "eu.midnightdust.blur.fabric.BlurFabric"
+    ]
+  },
+  "contact": {
+    "homepage": "https://modrinth.com/mod/blur-fabric",
+    "sources": "https://github.com/Motschen/Blur",
+    "issues": "https://github.com/Motschen/Blur/issues"
+  },
+  "authors": [
+    "Motschen",
+    "tterrag1098",
+    "Pyrofab",
+    "backryun",
+    "byquanton"
+  ],
+  "description": "Various enhancements for the blur effect behind Minecraft GUIs",
+  "mixins": [
+    "blur.mixins.json",
+    "blur_compat.mixins.json"
+  ],
+  "depends": {
+    "minecraft": ">=1.20.5"
+  }
+}